网页访问功能的问题。

梦游Bdr

最近在写网页访问这个功能，我想知道返回COOKIE给参数的变量这段代码怎么写。

Hoibben

api还是对象呢？精易模块都已经开源啦，你可以参考下。。。

梦游Bdr

Hoibben 发表于 2013-11-2 23:02
api还是对象呢？精易模块都已经开源啦，你可以参考下。。。

是API对象，能教下不

Hoibben

梦游Bdr 发表于 2013-11-2 23:23
是API对象，能教下不

自己看下精易模块的源码吧。。。

梦游Bdr

Hoibben 发表于 2013-11-2 23:24
自己看下精易模块的源码吧。。。

....。。

Cramps

[e]
.版本 2

.子程序 网页_访问, 字节集, 公开, 使用WinInet的方式访问网页
.参数 网址, 文本型, , 完整的网页地址,必须包含http://或者https://
.参数 访问方式, 整数型, 可空, 0=GET 1=POST
.参数 提交信息, 文本型, 可空, POST专用
.参数 提交Cookies, 文本型, 参考 可空, 本参数传递变量时会自动回传返回的Cookie
.参数 返回Cookies, 文本型, 可空, 返回的Cookie
.参数 附加协议头, 文本型, 可空, 一行一个请用换行符隔开
.参数 返回协议头, 文本型, 参考 可空, Location
.参数 禁止重定向, 逻辑型, 可空, 默认不禁止网页重定向
.参数 字节集提交, 字节集, 可空, 提交字节集数据
.参数 代理地址, 文本型, 可空, 代理地址，格式为 8.8.8.8:88
.参数 完整协议头, 文本型, 参考 可空, 返回完整的协议头
.局部变量 局_Internet句柄, 整数型
.局部变量 局_Internet连接句柄, 整数型
.局部变量 局_HTTP请求句柄, 整数型
.局部变量 局_计次, 整数型
.局部变量 局_字节集, 字节集
.局部变量 局_访问方式, 文本型
.局部变量 局_User_Agent, 文本型
.局部变量 局_返回Cookies, 文本型, , "0"
.局部变量 局_页面内容, 字节集
.局部变量 局_请求标记, 整数型
.局部变量 局_重定向地址, 文本型

局_访问方式 ＝ 选择 (访问方式 ＝ 1, “POST”, “GET”)
.如果 (寻找文本 (附加协议头, “User-Agent:”, , 真) ≠ -1)
局_User_Agent ＝ 删首尾空 (文本_取出中间文本 (附加协议头, “User-Agent:”, #换行符))
.如果真 (局_User_Agent ＝ “”)
局_User_Agent ＝ 内部_协议头取值 (附加协议头)
.如果真结束

.否则
局_User_Agent ＝ “Mozilla/4.0 (compatible; MSIE 9.0; Windows NT 6.1; 125LA; .NET CLR 2.0.50727; .NET CLR 3.0.04506.648; .NET CLR 3.5.21022)”
.如果结束

.如果 (是否为空 (代理地址))
局_Internet句柄 ＝ InternetOpenA (局_User_Agent, 1, 字符 (0), 字符 (0), 0)
.否则
局_Internet句柄 ＝ InternetOpenA (局_User_Agent, 3, 到文本 (“http=” ＋ 代理地址), “”, 0)
.如果结束

.如果真 (局_Internet句柄 ＝ 0)
InternetCloseHandle (局_Internet句柄)
返回 ({ })
.如果真结束

局_Internet连接句柄 ＝ InternetConnectA (局_Internet句柄, 网页_取域名 (网址), 网页_取端口 (网址), 字符 (0), 字符 (0), 3, 0, 0)
.如果真 (局_Internet连接句柄 ＝ 0)
InternetCloseHandle (局_Internet连接句柄)
InternetCloseHandle (局_Internet句柄)
返回 ({ })
.如果真结束

局_请求标记 ＝ 位或 (#INTERNET_FLAG_RELOAD, #INTERNET_COOKIE_THIRD_PARTY)
.如果真 (取反 (是否为空 (提交Cookies)))
局_请求标记 ＝ 位或 (局_请求标记, #INTERNET_FLAG_NO_COOKIES)
.如果真结束

.如果真 (禁止重定向)
局_请求标记 ＝ 位或 (局_请求标记, #INTERNET_FLAG_NO_AUTO_REDIRECT)
.如果真结束

.如果 (到小写 (取文本左边 (网址, 5)) ＝ “https”)
局_请求标记 ＝ 位或 (局_请求标记, #INTERNET_FLAG_SECURE)
.否则
局_请求标记 ＝ 位或 (局_请求标记, #INTERNET_FLAG_IGNORE_REDIRECT_TO_HTTPS)
.如果结束

局_HTTP请求句柄 ＝ HttpOpenRequestA (局_Internet连接句柄, 局_访问方式, 网页_取页面地址 (网址), “HTTP/1.1”, 字符 (0), 字符 (0), 局_请求标记, 0)
.如果真 (局_HTTP请求句柄 ＝ 0)
InternetCloseHandle (局_HTTP请求句柄)
InternetCloseHandle (局_Internet连接句柄)
InternetCloseHandle (局_Internet句柄)
返回 ({ })
.如果真结束

.如果真 (寻找文本 (附加协议头, “Referer:”, , 假) ＝ -1)
.判断开始 (附加协议头 ＝ “”)
附加协议头 ＝ “Referer: ” ＋ 网址
.默认
附加协议头 ＝ 附加协议头 ＋ #换行符 ＋ “Referer: ” ＋ 网址
.判断结束

.如果真结束

.如果真 (寻找文本 (附加协议头, “Accept:”, , 假) ＝ -1)
附加协议头 ＝ 附加协议头 ＋ #换行符 ＋ “Accept: */*”
.如果真结束

.如果真 (寻找文本 (附加协议头, “Accept-Language:”, , 假) ＝ -1)
附加协议头 ＝ 附加协议头 ＋ #换行符 ＋ “Accept-Language: zh-cn”
.如果真结束

.如果真 (寻找文本 (附加协议头, “Content-Type:”, , 假) ＝ -1)
附加协议头 ＝ 附加协议头 ＋ #换行符 ＋ “Content-Type: application/x-www-form-urlencoded”
.如果真结束

.如果真 (提交Cookies ≠ “”)
附加协议头 ＝ 附加协议头 ＋ #换行符 ＋ “Cookie: ” ＋ 提交Cookies
.如果真结束

.判断开始 (访问方式 ＝ 0)
HttpSendRequestA (局_HTTP请求句柄, 附加协议头, 取文本长度 (附加协议头), “”, 0)
.默认
.如果真 (字节集提交 ＝ { })
字节集提交 ＝ 到字节集 (提交信息)
.如果真结束
HttpSendRequestA_字节集 (局_HTTP请求句柄, 附加协议头, 取文本长度 (附加协议头), 字节集提交, 取字节集长度 (字节集提交))
.判断结束

局_计次 ＝ 0
.判断循环首 (真)
局_字节集 ＝ 取空白字节集 (1024)
InternetReadFile (局_HTTP请求句柄, 局_字节集, 1024, 局_计次)
.如果 (局_计次 ＝ 0)
跳出循环 ()
.否则
局_页面内容 ＝ 局_页面内容 ＋ 取字节集左边 (局_字节集, 局_计次)
.如果结束

.判断循环尾 ()

完整协议头 ＝ 取空白文本 (5000)
HttpQueryInfoA (局_HTTP请求句柄, 22, 完整协议头, 5000, 0)
InternetCloseHandle (局_HTTP请求句柄)
InternetCloseHandle (局_Internet连接句柄)
InternetCloseHandle (局_Internet句柄)

局_返回Cookies ＝ 分割文本 (完整协议头, #换行符, )
返回Cookies ＝ “”
.计次循环首 (取数组成员数 (局_返回Cookies), 局_计次)
.如果真 (寻找文本 (局_返回Cookies [局_计次], “Location:”, , 假) ≠ -1)
返回协议头 ＝ 内部_协议头取值 (局_返回Cookies [局_计次])
.如果真结束

.如果真 (寻找文本 (局_返回Cookies [局_计次], “Set-Cookie”, , 假) ≠ -1)
返回Cookies ＝ 返回Cookies ＋ 删首尾空 (文本_取出中间文本 (局_返回Cookies [局_计次], “Set-Cookie:”, “;”)) ＋ “; ”
.如果真结束

.计次循环尾 ()
返回Cookies ＝ 取文本左边 (返回Cookies, 取文本长度 (返回Cookies) － 2)
.如果真 (取反 (是否为空 (提交Cookies)))
网页_Cookie合并更新 (提交Cookies, 返回Cookies)
.如果真结束

.如果真 (返回协议头 ＝ “”)
返回协议头 ＝ 完整协议头
.如果真结束
' ==========酌情屏蔽===========
.如果真 (文本_取出中间文本 (完整协议头, “HTTP/1.1 ”, “ Moved”) ＝ “301”)
局_重定向地址 ＝ 返回协议头 ＋ 网页_取页面地址 (网址)
返回协议头 ＝ “”
返回 (网页_访问 (局_重定向地址, 访问方式, 提交信息, 提交Cookies, 返回Cookies, 附加协议头, 返回协议头, 禁止重定向, 字节集提交, 代理地址, 完整协议头))
.如果真结束
' ==========酌情屏蔽===========
局_计次 ＝ 寻找字节集 (局_页面内容, 到字节集 (“utf-8”), )
.如果真 (局_计次 ≠ -1 且 局_计次 ＜ 500 或 寻找文本 (完整协议头, “utf-8”, , 真) ≠ -1)
局_页面内容 ＝ 内部_Utf8到Ansi (局_页面内容)
.如果真结束
返回 (局_页面内容)

[/e]

最佳吧，顺便帮你把模块源码发上来了。
精易模块源码3.4.zip (487.51 KB, 下载次数: 0)

2013-11-4 19:01 上传

点击文件名下载附件

QQ：995238212

梦游Bdr

Cramps 发表于 2013-11-4 19:01
[e]
.版本 2

....网页访问API我懂用，就是不知道返回COOKIE的代码怎么写 。我想要的是写返回COOKIE的步奏，也就是说第一步怎么做，第二步怎么做，我不是想要代码，我想不看别人源码情况下自己尝试写。

Cramps

梦游Bdr 发表于 2013-11-4 19:52
....网页访问API我懂用，就是不知道返回COOKIE的代码怎么写 。我想要的是写返回COOKIE的步奏，也就是说第 ...

我也不懂。源码给你发上了。= =满意给最佳就可以了