懒惰算法实现高速图像模糊（源代码）

微凉

高速模糊.rar (7.88 KB, 下载次数: 68)

2012-6-21 16:48 上传

点击文件名下载附件
下载积分: 精币 -2 枚

这个速度绝对一流，比这个论坛里的任何其他相关代码都块。

转载请保留作者信息。


'*****************************************************************************************
'**    函 数 名 ：  FastBlur
'**    输    入 ：  Radius   -   模糊的半径
'**    输    出 ：  是否成功
'**    功能描述 ：  普通的均值模糊
'**    开发日期 ：  2008-1-17
'**    作    者 ：  laviewpbt
'**    联系方式：   33184777
'**    修改日期 ：  2008-5-22
'**    版    本 ：  Version 1.3.1
'**    转载请不要删除以上信息
'****************************************************************************************

Public Function FastBlur(Optional ByVal Radius As Long = 3) As Boolean

    Dim x                   As Long, y                      As Long
    Dim Rad                 As Long, Circumference          As Long
    Dim SumRowRed           As Long, SumRowGreen            As Long
    Dim SumRowBlue          As Long, mPtrC                  As Long
    Dim Width               As Long, Height                 As Long
    Dim DataArr(0 To 2)     As Byte, pDataArr(0 To 0)       As Long
    Dim OldArrPtr           As Long, OldpArrPtr             As Long
    Dim DataArrC(0 To 2)    As Byte, pDataArrC(0 To 0)      As Long
    Dim OldArrPtrC          As Long, OldpArrPtrC            As Long
    Dim Left                As Long, Right                  As Long
    Dim Top                 As Long, Bottom                 As Long
    Dim TempT               As Long, TempB                  As Long
     
    If mHdc  <> 0 Or mBmpInfo.biBitCount = 32 Then
        If Radius  < 1 Then Radius = 1
        If Radius > 500 Then Radius = 500                   '修正参数范围
        Width = Me.Width: Height = Me.Height
        Rad = Radius
        Circumference = Rad * 2 + 1
         
        MakePoint VarPtrArray(DataArr), VarPtrArray(pDataArr), OldArrPtr, OldpArrPtr   '绑定模拟指针
        MakePoint VarPtrArray(DataArrC), VarPtrArray(pDataArrC), OldArrPtrC, OldpArrPtrC
        mPtrC = GlobalAlloc(GPTR, mBmpInfo.biSizeImage)                                 '因为模糊会破坏原来的像素，所以要是用一个备份
        CopyMemory ByVal mPtrC, ByVal mPtr, mBmpInfo.biSizeImage                        '复制图像数据
         
        ReDim SumRed(Width - 1) As Long
        ReDim SumGreen(Width - 1) As Long
        ReDim SumBlue(Width - 1) As Long
        ReDim SumNum(Width - 1) As Long         '有多少个像素参加了累加
         
        For x = 0 To Rad                '循环无需从-Rad to Rad ，因为我们明确知道在-Rad到0处图像无数据
            For y = 0 To Rad            '计算左上角第一个像素的模糊化值，记录下各颜色分量和有效像素数
                pDataArrC(0) = mPtrC + mWidthBytes * y + x * 4      '指向我们需要的数句在备份数据中的地址（首地址+高度*扫描行宽度+宽度*每像素字节数）
                SumRed(0) = SumRed(0) + DataArrC(2)                 '累加值
                SumGreen(0) = SumGreen(0) + DataArrC(1)
                SumBlue(0) = SumBlue(0) + DataArrC(0)
                SumNum(0) = SumNum(0) + 1                           '计数器加一
            Next
        Next
        pDataArr(0) = mPtr + 4                                      '指向原始数据待要修改点的地址
        DataArr(2) = SumRed(0) \ SumNum(0)                          '修改原始数据
        DataArr(1) = SumGreen(0) \ SumNum(0)
        DataArr(0) = SumBlue(0) \ SumNum(0)

'*********************************************第一阶段结束*******************************************
         
        For x = 1 To Width - 1                                      '计算第一行像素除(0,0)点外其他像素的模糊值
            Left = x - Rad - 1                                      '水平方向循环起始处
            Right = x + Rad                                         '水平方向循环终止处
            SumRed(x) = SumRed(x - 1)                               '先复制前一个像素点相关信息
            SumGreen(x) = SumGreen(x - 1)   '
            SumBlue(x) = SumBlue(x - 1)
            SumNum(x) = SumNum(x - 1)
            For y = 0 To Rad                                        '我们可以明确知道第一行像素在垂直方向上的领域只需从0开始
                If y  < Height Then                                  '防止在rad>Height的时候出错
                    If Left >= 0 Then                               '是有效的像素
                        pDataArrC(0) = mPtrC + mWidthBytes * y + Left * 4   '寻址
                        SumRed(x) = SumRed(x) - DataArrC(2)         '对第一行的其他像素，模糊值等于前一个像素的模糊值减去模糊区域最左侧还要左一个单位的总和然后加上最右侧区域的那列的模糊值
                        SumGreen(x) = SumGreen(x) - DataArrC(1)
                        SumBlue(x) = SumBlue(x) - DataArrC(0)
                        SumNum(x) = SumNum(x) - 1                   '计数器也要加1
                    End If
                    If Right  < Width Then
                        pDataArrC(0) = mPtrC + mWidthBytes * y + Right * 4  '加上最右侧那一列的像素（如果存在的话）
                        SumRed(x) = SumRed(x) + DataArrC(2)
                        SumGreen(x) = SumGreen(x) + DataArrC(1)
                        SumBlue(x) = SumBlue(x) + DataArrC(0)
                        SumNum(x) = SumNum(x) + 1                           '计数器也要加1
                    End If
                End If
            Next
            pDataArr(0) = mPtr + x * 4                              '计算要修改处的地址
            DataArr(2) = SumRed(x) \ SumNum(x)
            DataArr(1) = SumGreen(x) \ SumNum(x)
            DataArr(0) = SumBlue(x) \ SumNum(x)
        Next                                                        '至此，第一行像素的模糊值计算完毕
         
  '*********************************************第二阶段结束*******************************************
For y = 1 To Height - 1                 '从第二行开始算起了
            Top = y - Rad - 1
            Bottom = y + Rad
            SumRowRed = 0
            SumRowGreen = 0
            SumRowBlue = 0
            TempT = mPtrC + mWidthBytes * Top           '为了加快计算速度
            TempB = mPtrC + mWidthBytes * Bottom
            For x = 0 To Rad                            '计算每行的第一个像素的模糊值
                If x  < Width Then                       '在合理的范围内
                    If Top >= 0 Then                    '减去不在该像素领域的一行像素累加和
                        pDataArrC(0) = TempT + x * 4
                        SumRowRed = SumRowRed - DataArrC(2)     '等于上一行的像素模糊值减去最上行还上一行的像素值加上最下部的像素和
                        SumRowGreen = SumRowGreen - DataArrC(1)
                        SumRowBlue = SumRowBlue - DataArrC(0)
                        SumNum(0) = SumNum(0) - 1
                    End If
                    If Bottom  < Height Then             '加上新增像素的一行像素累加和
                        pDataArrC(0) = TempB + x * 4
                        SumRowRed = SumRowRed + DataArrC(2)
                        SumRowGreen = SumRowGreen + DataArrC(1)
                        SumRowBlue = SumRowBlue + DataArrC(0)
                        SumNum(0) = SumNum(0) + 1
                    End If
                End If
            Next
            SumRed(0) = SumRed(0) + SumRowRed
            SumGreen(0) = SumGreen(0) + SumRowGreen
            SumBlue(0) = SumBlue(0) + SumRowBlue
            pDataArr(0) = mPtr + mWidthBytes * y            '更新该点
            DataArr(2) = SumRed(0) \ SumNum(0)
            DataArr(1) = SumGreen(0) \ SumNum(0)
            DataArr(0) = SumBlue(0) \ SumNum(0)
            
            For x = 1 To Width - 1        '计算一行的其他像素
                Left = x - Rad - 1
                If Left >= 0 Then
                    If Top >= 0 Then
                        pDataArrC(0) = TempT + Left * 4         '加上新增领域的一列像素累加和
                        SumRowRed = SumRowRed + DataArrC(2)
                        SumRowGreen = SumRowGreen + DataArrC(1)
                        SumRowBlue = SumRowBlue + DataArrC(0)
                    End If
                    If Bottom  < Height Then
                        pDataArrC(0) = TempB + Left * 4         '减去不在该像素领域一列像素累加和
                        SumRowRed = SumRowRed - DataArrC(2)
                        SumRowGreen = SumRowGreen - DataArrC(1)
                        SumRowBlue = SumRowBlue - DataArrC(0)
                    End If
                End If
                          
                If Top  < 0 Then
                    If x >= Radius And x  < Width - Radius Then
                        SumNum(x) = SumNum(x) + Circumference   '移入一行像素数
                    ElseIf x  < Radius Then
                        SumNum(x) = SumNum(x) + Radius + x + 1
                    Else
                        SumNum(x) = SumNum(x) + Radius + (Width - x)
                    End If
                End If
                If Bottom >= Height Then
                    If x >= Radius And x  < Width - Radius Then
                        SumNum(x) = SumNum(x) - Circumference
                    ElseIf x  < Radius Then
                        SumNum(x) = SumNum(x) - (Radius + x + 1)    '移出一行像素
                    Else
                        SumNum(x) = SumNum(x) - (Radius + (Width - x))
                    End If
                End If
                 
                Right = x + Rad
                If Right  < Width Then
                    If Top >= 0 Then
                        pDataArrC(0) = TempT + Right * 4            '同样的道理
                        SumRowRed = SumRowRed - DataArrC(2)
                        SumRowGreen = SumRowGreen - DataArrC(1)
                        SumRowBlue = SumRowBlue - DataArrC(0)
                    End If
                    If Bottom  < Height Then
                        pDataArrC(0) = TempB + Right * 4
                        SumRowRed = SumRowRed + DataArrC(2)
                        SumRowGreen = SumRowGreen + DataArrC(1)
                        SumRowBlue = SumRowBlue + DataArrC(0)
                    End If
                End If
               
                SumRed(x) = SumRed(x) + SumRowRed
                SumGreen(x) = SumGreen(x) + SumRowGreen
                SumBlue(x) = SumBlue(x) + SumRowBlue
                  
                pDataArr(0) = pDataArr(0) + 4               '更新数据
                DataArr(2) = SumRed(x) \ SumNum(x)          '对于图像数据用右除足够了
                DataArr(1) = SumGreen(x) \ SumNum(x)
                DataArr(0) = SumBlue(x) \ SumNum(x)
            Next
        Next
        GlobalFree mPtrC                                    '释放内存
        FreePoint VarPtrArray(DataArr), VarPtrArray(pDataArr), OldArrPtr, OldpArrPtr        '释放模拟指针
        FreePoint VarPtrArray(DataArrC), VarPtrArray(pDataArrC), OldArrPtrC, OldpArrPtrC
        FastBlur = True
    End If
End Function

无柏

看看…………

疍疍し

额，遇到高人了。。。

但是，最蛋疼还是。。。我不懂函数

疍疍し

更不懂VB。。无语了

shichaoran88

下下来研究下

指尖流淌

看不懂啊！~

onlydbg

看到了一个转字

914417177

不错学习了。。。

网络注册会员

还要这样的啊