自制时间框

童话世界

.版本 2
.程序集 窗口程序集1
.程序集变量 编辑框, 编辑框
.子程序 _编辑框1_调节钮被按下
.参数 按钮值, 整数型
.局部变量 选择位置
.局部变量 文本, 文本型
.如果真 (编辑框.被选择文本 ＝ “”)
    编辑框.起始选择位置 ＝ 0
    编辑框.被选择字符数 ＝ 2
.如果真结束
选择位置 ＝ 编辑框.起始选择位置
文本 ＝ 到文本 (到数值 (编辑框.被选择文本) ＋ 按钮值)
.如果 (选择位置 ＜ 3)
    .如果 (到数值 (文本) ＜ 0)
        文本 ＝ “23”
    .否则
        .如果 (到数值 (文本) ＞ 23)
            文本 ＝ “0”
        .否则
        .如果结束
    .如果结束
.否则
    .如果 (到数值 (文本) ＜ 0)
        文本 ＝ “59”
    .否则
        .如果 (到数值 (文本) ＞ 59)
            文本 ＝ “0”
        .否则
        .如果结束
    .如果结束
.如果结束
.如果真 (取文本长度 (文本) ＝ 1)
    文本 ＝ “0” ＋ 文本
.如果真结束
编辑框.被选择文本 ＝ 文本
编辑框.起始选择位置 ＝ 选择位置
编辑框.被选择字符数 ＝ 2
.子程序 _编辑框1_鼠标左键被放开, 逻辑型
.参数 横向位置, 整数型
.参数 纵向位置, 整数型
.参数 功能键状态, 整数型
.如果 (编辑框.起始选择位置 ＜ 3)
    编辑框.起始选择位置 ＝ 0
.否则
    .如果 (编辑框.起始选择位置 ＞ 2 且 编辑框.起始选择位置 ＜ 6)
        编辑框.起始选择位置 ＝ 3
    .否则
        编辑框.起始选择位置 ＝ 6
    .如果结束
.如果结束
编辑框.被选择字符数 ＝ 2
.子程序 __启动窗口_创建完毕
.局部变量 日期时间, 日期时间型
.局部变量 文本, 文本型, , "3"

_启动窗口.底图 ＝ #图片1
日期时间 ＝ 取现行时间 ()
编辑框 ＝ 编辑框1
编辑框.内容 ＝ “”
文本 [1] ＝ 到文本 (取小时 (日期时间))
文本 [2] ＝ 到文本 (取分钟 (日期时间))
文本 [3] ＝ 到文本 (取秒 (日期时间))
.如果真 (取文本长度 (文本 [1]) ＝ 1)
    文本 [1] ＝ “0” ＋ 文本 [1]
.如果真结束
.如果真 (取文本长度 (文本 [2]) ＝ 1)
    文本 [2] ＝ “0” ＋ 文本 [2]
.如果真结束
.如果真 (取文本长度 (文本 [3]) ＝ 1)
    文本 [3] ＝ “0” ＋ 文本 [3]
.如果真结束
编辑框.加入文本 (文本 [1], “:”, 文本 [2], “:”, 文本 [3])
' 原过程 ＝ 置窗口过程 (编辑框3.取窗口句柄 (), -4, &消息处理)
加载皮肤 (15)

.子程序 _编辑框1_字符输入, 整数型
.参数 字符代码, 整数型
.局部变量 文本, 文本型
.局部变量 选择位置
.局部变量 数值
.如果真 (编辑框.被选择文本 ＝ “” 或 编辑框.被选择字符数 ≠ 2 或 取反 (编辑框.起始选择位置 ＝ 0 或 编辑框.起始选择位置 ＝ 3 或 编辑框.起始选择位置 ＝ 6))
    返回 (0)
.如果真结束
数值 ＝ 到数值 (字符 (字符代码))
选择位置 ＝ 编辑框.起始选择位置
文本 ＝ 编辑框.被选择文本 ＋ 到文本 (数值)
文本 ＝ 到文本 (到数值 (文本))
.如果 (选择位置 ＜ 3)
    .如果 (到数值 (文本) ＜ 0)
        文本 ＝ 选择 (数值 ＞ 23, “23”, 到文本 (数值))
    .否则
        .如果 (到数值 (文本) ＞ 23)
            文本 ＝ 选择 (数值 ＜ 0, “0”, 到文本 (数值))
        .否则
        .如果结束
    .如果结束
.否则
    .如果 (到数值 (文本) ＜ 0)
        文本 ＝ 选择 (数值 ＞ 59, “59”, 到文本 (数值))
    .否则
        .如果 (到数值 (文本) ＞ 59)
            文本 ＝ 选择 (数值 ＜ 0, “0”, 到文本 (数值))
        .否则
        .如果结束
    .如果结束
.如果结束
.如果真 (取文本长度 (文本) ＝ 1)
    文本 ＝ “0” ＋ 文本
.如果真结束
编辑框.被选择文本 ＝ 文本
编辑框.起始选择位置 ＝ 选择位置
编辑框.被选择字符数 ＝ 2
返回 (0)
.子程序 _编辑框1_按下某键, 逻辑型
.参数 键代码, 整数型
.参数 功能键状态, 整数型
.如果真 (键代码 ＝ #退格键 或 键代码 ＝ #Del键 或 功能键状态 ≠ 0)
    返回 (假)
.如果真结束
.如果真 (键代码 ＝ #左光标键 或 键代码 ＝ #右光标键 或 键代码 ＝ #上光标键 或 键代码 ＝ #下光标键)
    .如果 (键代码 ＝ #上光标键 或 键代码 ＝ #下光标键)
        _编辑框1_调节钮被按下 (选择 (键代码 ＝ #上光标键, 1, -1))
    .否则
        .如果 (键代码 ＝ #右光标键)
            编辑框.起始选择位置 ＝ 编辑框.起始选择位置 ＋ 3
            .如果真 (编辑框.起始选择位置 ＝ 8)
                编辑框.起始选择位置 ＝ 0
            .如果真结束
        .否则
            编辑框.起始选择位置 ＝ 编辑框.起始选择位置 － 1
        .如果结束
        编辑框.被选择字符数 ＝ 2
        _编辑框1_鼠标左键被放开 (0, 0, 0)
    .如果结束
    返回 (假)
.如果真结束

.子程序 _编辑框1_鼠标位置被移动, 逻辑型
.参数 横向位置, 整数型
.参数 纵向位置, 整数型
.参数 功能键状态, 整数型
返回 (假)

讲不出再见

源码呢？？

杜杜哎哟

如果有效果截图就好啦

宇智波·佐助

你这开源太壮观了